CFSITHMASTER

Array Reverse

Thu, 07 Jul 2011 17:24:00 -0500

I recently came in need of a way to reverse the order of the elements in my array. Here's what I came up with.


array function reverseArray(required array inputArray)
	hint="reverses the order of the array"
	output="false"
{
	var j = arrayLen(arguments.inputArray);

	for (var i=1;i<=arrayLen(arguments.inputArray)/2;i++) {
		arraySwap(arguments.inputArray,i,j--);
	}

	return arguments.inputArray;
}

Query To Array

Thu, 30 Jun 2011 11:25:00 -0500

Here's another one if you want to turn the query variable into an array of structures.


array function queryToArray (required query data)
	output="false"
{
	local.columns = listToArray(arguments.data.columnList);

	local.queryArray = [];

	for (local.rowIndex = 1; local.rowIndex <= arguments.data.recordCount; local.rowIndex++) {
		local.row = {};

		for (local.columnIndex = 1; local.columnIndex <= arrayLen(local.columns); local.columnIndex++) {
			local.columnName = local.columns[local.columnIndex];

			local.row[local.columnName] = arguments.data[local.columnName][local.rowIndex];
		}

		arrayAppend(local.queryArray, local.row);
	}

	return(local.queryArray);
}

Query To Struct

Thu, 30 Jun 2011 11:20:00 -0500

Below is a very handy function to convert a query variable into a structure of structure. Enjoy.


struct function queryToStruct(required query data, boolean unique=false)
	output="false"
{
	var result = {};
	var columns = listToArray(arguments.data.columnList);

	for (var r=1;r<=arguments.data.recordCount;r++) {
		var row = {};

		for (var c=1;c<=arrayLen(columns);c++) {
			var columnName = columns[c];
			structInsert(row, columnName, arguments.data[columnName][r]);
		}

		structInsert(result, r, row);
	}

	if (structCount(result) == 1 && arguments.unique) {
		result = result[structKeyArray(result)[1]];
	}

	return result;
}